b72a46db68
Some checks failed
Update All Top Ranking Issues / update_top_ranking_issues (push) Has been cancelled
Triage Project Sync (#84) / Sync triage project (push) Has been cancelled
release_nightly / notify_on_failure (push) Has been cancelled
release_nightly / check_style (push) Has been cancelled
release_nightly / run_tests_windows (push) Has been cancelled
release_nightly / clippy_windows (push) Has been cancelled
release_nightly / bundle_linux_aarch64 (push) Has been cancelled
release_nightly / bundle_linux_x86_64 (push) Has been cancelled
release_nightly / bundle_mac_aarch64 (push) Has been cancelled
release_nightly / bundle_mac_x86_64 (push) Has been cancelled
release_nightly / bundle_windows_aarch64 (push) Has been cancelled
release_nightly / bundle_windows_x86_64 (push) Has been cancelled
release_nightly / build_nix_linux_x86_64 (push) Has been cancelled
release_nightly / build_nix_mac_aarch64 (push) Has been cancelled
release_nightly / update_nightly_tag (push) Has been cancelled
Hotfix Review Monitor / check-hotfix-reviews (push) Has been cancelled
Stale PR Review Reminder / check-stale-prs (push) Has been cancelled
Update Weekly Top Ranking Issues / update_top_ranking_issues (push) Has been cancelled
Bump collab-staging Tag / update-collab-staging-tag (push) Has been cancelled
compliance_check / scheduled_compliance_check (push) Has been cancelled
Single-commit orphan branch: full zed-industries/zed @ 8c74db0 source tree with a 3-file patch applied (no upstream history). Patch (crates/gpui_linux/src/linux/wayland/): - serial.rs: add SerialKind::KeyboardEnter - client.rs: store wl_keyboard.enter serial; add latest_serial_of() - window.rs: activate() uses keyboard-enter serial (Mutter focus gate) Mutter honors window activation only when the token carries the keyboard- focus serial from wl_keyboard.enter; GPUI used a stale mouse-press serial. See docs/tray-window-focus-wayland.md in logiguard. Co-Authored-By: Claude Fable 5 <noreply@anthropic.com>
196 lines
4.3 KiB
Scheme
196 lines
4.3 KiB
Scheme
(preproc_def
|
|
"#define" @context
|
|
name: (_) @name) @item
|
|
|
|
(preproc_function_def
|
|
"#define" @context
|
|
name: (_) @name
|
|
parameters: (preproc_params
|
|
"(" @context
|
|
")" @context)) @item
|
|
|
|
(namespace_definition
|
|
"inline"? @context
|
|
"namespace" @context
|
|
name: (_) @name) @item
|
|
|
|
(type_definition
|
|
"typedef" @context
|
|
declarator: (_) @name) @item
|
|
|
|
(struct_specifier
|
|
"struct" @context
|
|
name: (_) @name) @item
|
|
|
|
(class_specifier
|
|
"class" @context
|
|
name: (_) @name) @item
|
|
|
|
(enum_specifier
|
|
"enum" @context
|
|
[
|
|
"class"
|
|
"struct"
|
|
]? @context
|
|
name: (_) @name) @item
|
|
|
|
(union_specifier
|
|
"union" @context
|
|
name: (_) @name) @item
|
|
|
|
(enumerator
|
|
name: (_) @name) @item
|
|
|
|
(concept_definition
|
|
"concept" @context
|
|
name: (_) @name) @item
|
|
|
|
(declaration
|
|
[
|
|
(storage_class_specifier)
|
|
(type_qualifier)
|
|
]* @context
|
|
type: (_) @context
|
|
declarator: [
|
|
; The declaration may define multiple variables, using @item on the
|
|
; declarator so that they get distinct ranges.
|
|
(init_declarator
|
|
declarator: (_) @item @name)
|
|
(identifier) @item @name
|
|
] @item)
|
|
|
|
(function_definition
|
|
[
|
|
(storage_class_specifier)
|
|
(type_qualifier)
|
|
]* @context
|
|
type: (_)? @context
|
|
declarator: [
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))))
|
|
(reference_declarator
|
|
[
|
|
"&"
|
|
"&&"
|
|
] @context
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
]
|
|
(type_qualifier)? @context) @item
|
|
|
|
(declaration
|
|
[
|
|
(storage_class_specifier)
|
|
(type_qualifier)
|
|
]* @context
|
|
type: (_)? @context
|
|
declarator: [
|
|
(field_identifier) @name
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (field_identifier) @name)
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))))
|
|
(reference_declarator
|
|
[
|
|
"&"
|
|
"&&"
|
|
] @context
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
]
|
|
(type_qualifier)? @context) @item
|
|
|
|
(field_declaration
|
|
[
|
|
(storage_class_specifier)
|
|
(type_qualifier)
|
|
]* @context
|
|
type: (_) @context
|
|
declarator: [
|
|
(field_identifier) @name
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (field_identifier) @name)
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
(pointer_declarator
|
|
"*" @context
|
|
declarator: (pointer_declarator
|
|
"*" @context
|
|
declarator: (function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context))))
|
|
(reference_declarator
|
|
[
|
|
"&"
|
|
"&&"
|
|
] @context
|
|
(function_declarator
|
|
declarator: (_) @name
|
|
parameters: (parameter_list
|
|
"(" @context
|
|
")" @context)))
|
|
; Fields declarations may define multiple fields, and so @item is on the
|
|
; declarator so they each get distinct ranges.
|
|
] @item
|
|
(type_qualifier)? @context)
|
|
|
|
(comment) @annotation
|