logiguard fork: GPUI xdg-activation keyboard-focus serial fix

Single-commit orphan branch: full zed-industries/zed @ 8c74db0 source tree
with a 3-file patch applied (no upstream history).

Patch (crates/gpui_linux/src/linux/wayland/):
  - serial.rs: add SerialKind::KeyboardEnter
  - client.rs: store wl_keyboard.enter serial; add latest_serial_of()
  - window.rs: activate() uses keyboard-enter serial (Mutter focus gate)

Mutter honors window activation only when the token carries the keyboard-
focus serial from wl_keyboard.enter; GPUI used a stale mouse-press serial.
See docs/tray-window-focus-wayland.md in logiguard.

Co-Authored-By: Claude Fable 5 <noreply@anthropic.com>

extensions/proto/languages/proto/config.toml

@@ -0,0 +1,13 @@
+name = "Proto"
+grammar = "proto"
+path_suffixes = ["proto"]
+line_comments = ["// "]
+autoclose_before = ";:.,=}])>"
+brackets = [
+    { start = "{", end = "}", close = true, newline = true },
+    { start = "[", end = "]", close = true, newline = true },
+    { start = "(", end = ")", close = true, newline = true },
+    { start = "\"", end = "\"", close = true, newline = false, not_in = ["comment", "string"] },
+    { start = "'", end = "'", close = true, newline = false, not_in = ["comment", "string"] },
+    { start = "/*", end = " */", close = true, newline = false, not_in = ["comment", "string"] },
+]

extensions/proto/languages/proto/highlights.scm

@@ -0,0 +1,62 @@
+[
+  "syntax"
+  "package"
+  "option"
+  "optional"
+  "import"
+  "service"
+  "rpc"
+  "returns"
+  "message"
+  "enum"
+  "extend"
+  "oneof"
+  "repeated"
+  "reserved"
+  "to"
+] @keyword
+
+[
+  (key_type)
+  (type)
+  (message_name)
+  (enum_name)
+  (service_name)
+  (rpc_name)
+  (message_or_enum_type)
+] @type
+
+(enum_field
+  (identifier) @constant)
+
+[
+  (string)
+  "\"proto3\""
+] @string
+
+(int_lit) @number
+
+[
+  (true)
+  (false)
+] @boolean
+
+(comment) @comment
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "<"
+  ">"
+] @punctuation.bracket
+
+[
+  ";"
+  ","
+] @punctuation.delimiter
+
+"=" @operator

extensions/proto/languages/proto/indents.scm

@@ -0,0 +1,11 @@
+(_
+  "{"
+  "}" @end) @indent
+
+(_
+  "["
+  "]" @end) @indent
+
+(_
+  "("
+  ")" @end) @indent

extensions/proto/languages/proto/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

extensions/proto/languages/proto/outline.scm

@@ -0,0 +1,19 @@
+(message
+  "message" @context
+  (message_name
+    (identifier) @name)) @item
+
+(service
+  "service" @context
+  (service_name
+    (identifier) @name)) @item
+
+(rpc
+  "rpc" @context
+  (rpc_name
+    (identifier) @name)) @item
+
+(enum
+  "enum" @context
+  (enum_name
+    (identifier) @name)) @item

extensions/proto/languages/proto/textobjects.scm

@@ -0,0 +1,22 @@
+(message
+  (message_body
+    "{"
+    (_)* @class.inside
+    "}")) @class.around
+
+(enum
+  (enum_body
+    "{"
+    (_)* @class.inside
+    "}")) @class.around
+
+(service
+  "service"
+  (_)
+  "{"
+  (_)* @class.inside
+  "}") @class.around
+
+(rpc) @function.around
+
+(comment)+ @comment.around