47 lines
1.2 KiB
Bash
47 lines
1.2 KiB
Bash
# Maintainer: Mohammadreza Khani <mohamadreza.khani@proton.me>
|
|
pkgname=doh-forwarder
|
|
pkgver=0.1.0
|
|
pkgrel=1
|
|
pkgdesc="A lightweight DNS-over-HTTPS forwarder"
|
|
arch=('x86_64')
|
|
url="https://git.logicamp.dev/mohamad/doh-forwarder"
|
|
license=('MIT')
|
|
depends=('gcc-libs' 'openssl')
|
|
makedepends=('rust' 'cargo')
|
|
backup=('etc/doh-forwarder/config.toml')
|
|
source=("$pkgname::git+https://git.logicamp.dev/mohamad/doh-forwarder.git#tag=v${pkgver}"
|
|
'doh-forwarder.service'
|
|
'doh-forwarder.sysusers'
|
|
'doh-forwarder.conf')
|
|
sha256sums=('SKIP'
|
|
'SKIP'
|
|
'SKIP'
|
|
'SKIP')
|
|
|
|
build() {
|
|
cd "$pkgname"
|
|
cargo build --release --locked
|
|
}
|
|
|
|
check() {
|
|
cd "$pkgname"
|
|
cargo test --release --locked
|
|
}
|
|
|
|
package() {
|
|
cd "$pkgname"
|
|
|
|
# Binary
|
|
install -Dm755 "target/release/doh-forwarder" "$pkgdir/usr/bin/doh-forwarder"
|
|
|
|
# Config
|
|
install -Dm644 "$srcdir/doh-forwarder.conf" "$pkgdir/etc/doh-forwarder/config.toml"
|
|
|
|
# Systemd
|
|
install -Dm644 "$srcdir/doh-forwarder.service" "$pkgdir/usr/lib/systemd/system/doh-forwarder.service"
|
|
install -Dm644 "$srcdir/doh-forwarder.sysusers" "$pkgdir/usr/lib/sysusers.d/doh-forwarder.conf"
|
|
|
|
# License
|
|
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
}
|